'Dev/ActionScript' 카테고리의 글 목록

Flex3 in Action 이미지 출처 : 강컴

ActionScript에서 배열은 Array 를 사용하게 됩니다.
Java 와 달리 동적배열이어서 크기를 정하지 않고 임의대로 push, pop 등의 메소드를 통해 편리하게 사용할 수 있습니다. (Java에서는 ArrayList를 사용하시면 편리하죠!)

얼마전에 읽었던 Flex3 in Action 에 보면 'Working with ActionScript' chapter에 Array에 대해서 설명하고 있는데요, 여기에 다름과 같이 배열에 대해서 정의를 하고 있습니다.

1. Indexed arrays
2. Associative arrays

1번 Indexed arrays 는 우리가 흔히 사용하는 Array를 말합니다. 숫자 인덱스를 가지고 다음과 같이 값에 접근을 하게됩니다.

그리고 2번 Associative arrays는 흔히 연관배열 또는 해시(Hash)라고 부르는 배열로 key 값을 가지고 접근하게 됩니다. 책의 예제는 다음과 같습니다.

위의 예제는 이상없이 잘 동작합니다만, ActionScript 에서 연관배열(해시)를 위와 같이 사용하면 안됩니다.
그 이유는 Livedocs 에 잘 나와있습니다.

Array 클래스를 사용하여 번호가 매겨진 요소 대신 명명된 요소가 들어 있는 데이터 구조인 연결 배열(해시) 을 만들지 마십시오. 연결 배열을 만들려면 Object 클래스를 사용해야 합니다. ActionScript에서 Array 클래스를 사용하여 연결 배열을 만들 수는 있지만 이렇게 하면 연결 배열에 Array 클래스 메서드나 속성을 사용할 수 없습니다.

Livedocs 에서 발췌

ActionScript 에서는 Object 클래스를 이용하여 해시를 구현하라고 설명하고 있습니다. 물론 Object가 모든 클래스의 기본이 되기때문에, Array를 이용하여 연관배열(해시)를 만들 수는 있습니다. 하지만 해당 클래스를 만든 의미가 없어지죠. Array는 index를 이용한 배열로 설계된 것이기 때문입니다. 예를 들어 임의로 인스턴스화 시킬 수 있는 Sprite 객체를 연관배열로 사용한다는 것은 정말 황당한 일이라고 할 수 있겠습니다. 해당 목적에 맞게 사용해야 된다는 것이죠 ;)
아래에 Object로 연관배열을 사용하는 방법에 대해서 발췌했습니다.

Object 클래스를 사용하여 연결 배열을 만들 수 있습니다. 기본적으로 연결 배열은 Object 클래스의 인스턴스이며 키-값 쌍은 각각 속성과 속성 값으로 표현됩니다. 결합적 배열을 Object 데이터 유형을 사용하여 선언해야 하는 또 다른 이유는 이 경우 객체 리터럴을 사용하여 결합적 배열을 채울 수 있기 때문입니다. 단, Object 데이터 유형으로 선언하는 경우에만 가능합니다. 다음 예제에서는 객체 리터럴을 사용하여 연결 배열을 만들고 도트 연산자와 배열 액세스 연산자를 사용하여 항목에 액세스한 다음 새 속성을 만들어 키-값 쌍을 새로 추가합니다.

Livedocs 에서 발췌

위와 같이 Object를 이용하여 연결배열(해시)를 만들수 있습니다.
그리고 추가적으로 해당 값의 키(Key)값을 다른 객체로 하기 위해서 ActionScript 3.0에서는 Dictionary 클래스를 제공합니다.

Dictionary 클래스를 사용하면 키 비교에 완전 항등 연산자(===)를 사용하는 동적 속성 컬렉션을 만들 수 있습니다. 객체를 키로 사용하는 경우 객체에 toString()을 호출하여 반환되는 값이 아니라 객체의 ID가 객체를 찾는 데 사용됩니다.

다음 명령문은 Dictionary 객체와 키 객체 사이의 관계를 보여 줍니다.

var dict:Dictionary = new Dictionary(); var obj:Object = new Object(); var key:Object = new Object(); key.toString = function() { return "key" } dict[key] = "Letters"; obj["key"] = "Letters"; dict[key] == "Letters"; // true obj["key"] == "Letters"; // true obj[key] == "Letters"; // true because key == "key" is true because key.toString == "key" dict["key"] == "Letters"; // false because "key" === key is false delete dict[key]; //removes the key

Livedocs 에서 발췌

실제 해당 클래스의 구현 목적대로 사용하여야 오동작을 막을 수 있습니다. 게다가 협업시에 큰 걸림돌이 될 수 도 있습니다.
이 글을 읽으시는 분들은 사용하시는 클래스가 구현된 목적대로 사용하고 계신가요?

좋은 하루 되세요 :-)

ps. 책이 한글판으로 발간된다는 소식은 없는데, 만약 된다면 위의 오류에 대해서는 수정해서 나왔으면 좋겠네요.
ps2. AS 한글문서에는 연관배열이 아닌 연결배열로 번역이 되어있더군요. 정확하게 무엇이 맞는지는 저도 잘 모르겠네요 :)

'Dev > ActionScript' 카테고리의 다른 글

[Flex & Flash] ActionScript 3.0에서 BMP 파일 로드하기 (11)	2009.06.18
[Flex&Flash] useCodePage = true 가 한글 깨짐 방지 코드라고? (26)	2009.03.27
[Flex] with 를 아십니까? (12)	2008.06.09
[Flex] int나 uint보다 Number를 쓰세요! (29)	2008.06.05
[Flex] for문 쓸때 조건문에 유의하자. (23)	2008.05.09

오랫만에 블로그로 인사드립니다. (__)

최근에 BMP 파일을 Flex 에서 읽어다 쓸 일이 생겼습니다.
Flex에서 이미지를 보여주는 컴포넌트인 Image 컴포넌트는 JPEG, PNG, GIF, SWF, SVG 같은 확장자만을 지원하고 BMP은 지원하고 있지 않기 때문에 BMP을 바로 넣을 수는 없습니다.(웹에서 BMP 를 쓰는 무식한 짓을 하면 안되겠죠.. ㅜㅜ 크기도 큰데 말입니다.) JPG 파일이면 Image 컴포넌트에서 바로 읽어다 쓸 수 있을텐데 참 난감합니다.

그럼 방법이 없느냐? 아닙니다.
어떤 멋진 분께서 BMPDecoder 를 만들어놓으셨네요! :) 이미 FlexComponent 카페에서도 공유되었던 내용입니다.

http://ntt.cc/2008/10/01/using-bmpdecoder-class-to-load-an-external-bmp-file-rle-compression-support.html

위의 블로그에 들어가보시면 간단한 사용법에 대해서 나오고 BMPDecoder 라이브러리도 보입니다. 다만 BMPDecoder.as 파일이 다운로드가 안되네요. BMPDecoder.as 파일은 '삶의 향기'라는 블로그에 간단한 예제와 함께 업로드 되어 있으니 다운받아 사용하시면 되겠습니다.

간단하게 FP10 에서 추가된 FileReference의 load() 메소드를 이용해, BMP파일을 불러다 Image 컴포넌트에 넣는 예제를 만들어봤습니다. 예제 구성은 위에서 소개해드린 '삶의 향기' 블로그에 소개된 코드를 이용했습니다.

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="{init()}" 
	backgroundGradientAlphas="[1.0, 1.0]" backgroundGradientColors="[#FFFFFF, #FFFFFF]">
	<mx:Script>
		<![CDATA[
			import mcmall.core.codec.BMPDecoder;
			private var fileRef:FileReference;
			private function init():void
			{
				fileRef = new FileReference();
				fileRef.addEventListener(Event.COMPLETE, completeHandler);
				fileRef.addEventListener(Event.SELECT, selectHandler);
			}
			
			private function bmpLoad():void
			{
				fileRef.browse([new FileFilter("BMP", "*.bmp")]);
			}

private function completeHandler(event:Event):void {
				var byteArray:ByteArray = new ByteArray();
				fileRef.data.readBytes(byteArray);

var bmpDecoder:BMPDecoder = new BMPDecoder();
				var tempBitmap:Bitmap = new Bitmap();
				tempBitmap.bitmapData = bmpDecoder.decode( byteArray ); 
				// byteArray BitmapData 로 디코딩 	
				
				imgBmp.load(tempBitmap);
				imgBmp.width = imgBmp.contentWidth;
				imgBmp.height = imgBmp.contentHeight;            
	        }
	
	        private function selectHandler(event:Event):void {
	            var file:FileReference = FileReference(event.target);
	            file.load();
	        }

]]>
	</mx:Script>
	<mx:VBox height="100%" width="100%" 
		horizontalCenter="0" verticalCenter="0" 
		verticalAlign="middle" horizontalAlign="center" >
		<mx:Image width="101" height="145" id="imgBmp"/>
		<mx:Button label="BMP Load" click="{bmpLoad()}"/>
	</mx:VBox>
</mx:Application>

package mcmall.core.codec { import flash.display.BitmapData; import flash.errors.IOError; import flash.utils.ByteArray; import flash.utils.Endian; public class BMPDecoder { //___________________________________________________________ const private const BITMAP_HEADER_TYPE:String = "BM"; private const BITMAP_FILE_HEADER_SIZE:int = 14; private const BITMAP_CORE_HEADER_SIZE:int = 12; private const BITMAP_INFO_HEADER_SIZE:int = 40; private const COMP_RGB:int = 0; private const COMP_RLE8:int = 1; private const COMP_RLE4:int = 2; private const COMP_BITFIELDS:int = 3; private const BIT1:int = 1; private const BIT4:int = 4; private const BIT8:int = 8; private const BIT16:int = 16; private const BIT24:int = 24; private const BIT32:int = 32; //___________________________________________________________ vars private var bytes:ByteArray; private var palette:Array; private var bd:BitmapData; private var nFileSize:uint; private var nReserved1:uint; private var nReserved2:uint; private var nOffbits:uint; private var nInfoSize:uint; private var nWidth:int; private var nHeight:int; private var nPlains:uint; private var nBitsPerPixel:uint; private var nCompression:uint; private var nSizeImage:uint; private var nXPixPerMeter:int; private var nYPixPerMeter:int; private var nColorUsed:uint; private var nColorImportant:uint; private var nRMask:uint; private var nGMask:uint; private var nBMask:uint; private var nRPos:uint; private var nGPos:uint; private var nBPos:uint; private var nRMax:uint; private var nGMax:uint; private var nBMax:uint; /** * Constructor */ public function BMPDecoder() { nRPos = 0; nGPos = 0; nBPos = 0; } /** * decoder * * @param BMP file ByteArray */ public function decode(data:ByteArray):BitmapData { bytes = data; bytes.endian = Endian.LITTLE_ENDIAN; bytes.position = 0; readFileHeader(); nInfoSize = bytes.readUnsignedInt(); switch (nInfoSize) { case BITMAP_CORE_HEADER_SIZE: readCoreHeader(); break; case BITMAP_INFO_HEADER_SIZE: readInfoHeader(); break; default: readExtendedInfoHeader(); break; } bd = new BitmapData(nWidth, nHeight); switch (nBitsPerPixel) { case BIT1: readColorPalette(); decode1BitBMP(); break; case BIT4: readColorPalette(); if (nCompression == COMP_RLE4) { decode4bitRLE(); } else { decode4BitBMP(); } break; case BIT8: readColorPalette(); if (nCompression == COMP_RLE8) { decode8BitRLE(); } else { decode8BitBMP(); } break; case BIT16: readBitFields(); checkColorMask(); decode16BitBMP(); break; case BIT24: decode24BitBMP(); break; case BIT32: readBitFields(); checkColorMask(); decode32BitBMP(); break; default: throw new VerifyError("invalid bits per pixel : " + nBitsPerPixel); } return bd; } /** * read BITMAP FILE HEADER */ private function readFileHeader():void { var fileHeader:ByteArray = new ByteArray(); fileHeader.endian = Endian.LITTLE_ENDIAN; try { bytes.readBytes(fileHeader, 0, BITMAP_FILE_HEADER_SIZE); if (fileHeader.readUTFBytes(2) != BITMAP_HEADER_TYPE) { throw new VerifyError("invalid bitmap header type"); } nFileSize = fileHeader.readUnsignedInt(); nReserved1 = fileHeader.readUnsignedShort(); nReserved2 = fileHeader.readUnsignedShort(); nOffbits = fileHeader.readUnsignedInt(); } catch (e:IOError) { throw new VerifyError("invalid file header"); } } /** * read BITMAP CORE HEADER */ private function readCoreHeader():void { var coreHeader:ByteArray = new ByteArray(); coreHeader.endian = Endian.LITTLE_ENDIAN; try { bytes.readBytes(coreHeader, 0, BITMAP_CORE_HEADER_SIZE - 4); nWidth = coreHeader.readShort(); nHeight = coreHeader.readShort(); nPlains = coreHeader.readUnsignedShort(); nBitsPerPixel = coreHeader.readUnsignedShort(); } catch (e:IOError) { throw new VerifyError("invalid core header"); } } /** * read BITMAP INFO HEADER */ private function readInfoHeader():void { var infoHeader:ByteArray = new ByteArray(); infoHeader.endian = Endian.LITTLE_ENDIAN; try { bytes.readBytes(infoHeader, 0, BITMAP_INFO_HEADER_SIZE - 4); nWidth = infoHeader.readInt(); nHeight = infoHeader.readInt(); nPlains = infoHeader.readUnsignedShort(); nBitsPerPixel = infoHeader.readUnsignedShort(); nCompression = infoHeader.readUnsignedInt(); nSizeImage = infoHeader.readUnsignedInt(); nXPixPerMeter = infoHeader.readInt(); nYPixPerMeter = infoHeader.readInt(); nColorUsed = infoHeader.readUnsignedInt(); nColorImportant = infoHeader.readUnsignedInt(); } catch (e:IOError) { throw new VerifyError("invalid info header"); } } /** * read the extend info of BITMAP INFO HEADER */ private function readExtendedInfoHeader():void { var infoHeader:ByteArray = new ByteArray(); infoHeader.endian = Endian.LITTLE_ENDIAN; try { bytes.readBytes(infoHeader, 0, nInfoSize - 4); nWidth = infoHeader.readInt(); nHeight = infoHeader.readInt(); nPlains = infoHeader.readUnsignedShort(); nBitsPerPixel = infoHeader.readUnsignedShort(); nCompression = infoHeader.readUnsignedInt(); nSizeImage = infoHeader.readUnsignedInt(); nXPixPerMeter = infoHeader.readInt(); nYPixPerMeter = infoHeader.readInt(); nColorUsed = infoHeader.readUnsignedInt(); nColorImportant = infoHeader.readUnsignedInt(); if (infoHeader.bytesAvailable >= 4) nRMask = infoHeader.readUnsignedInt(); if (infoHeader.bytesAvailable >= 4) nGMask = infoHeader.readUnsignedInt(); if (infoHeader.bytesAvailable >= 4) nBMask = infoHeader.readUnsignedInt(); } catch (e:IOError) { throw new VerifyError("invalid info header"); } } /** * read bitfields */ private function readBitFields():void { if (nCompression == COMP_RGB) { if (nBitsPerPixel == BIT16) { // RGB555 nRMask = 0x00007c00; nGMask = 0x000003e0; nBMask = 0x0000001f; } else { //RGB888; nRMask = 0x00ff0000; nGMask = 0x0000ff00; nBMask = 0x000000ff; } } else if ((nCompression == COMP_BITFIELDS) && (nInfoSize < 52)) { try { nRMask = bytes.readUnsignedInt(); nGMask = bytes.readUnsignedInt(); nBMask = bytes.readUnsignedInt(); } catch (e:IOError) { throw new VerifyError("invalid bit fields"); } } } /** * read color palette */ private function readColorPalette():void { var i:int; var len:int = (nColorUsed > 0) ? nColorUsed : Math.pow(2, nBitsPerPixel); palette = new Array(len); for (i = 0; i < len; ++i) { palette[i] = bytes.readUnsignedInt(); } } /** * decode 1 bit BMP */ private function decode1BitBMP():void { var x:int; var y:int; var i:int; var col:int; var buf:ByteArray = new ByteArray(); var line:int = nWidth / 8; if (line % 4 > 0) { line = ((line / 4 | 0) + 1) * 4; } try { for (y = nHeight - 1; y >= 0; --y) { buf.length = 0; bytes.readBytes(buf, 0, line); for (x = 0; x < nWidth; x += 8) { col = buf.readUnsignedByte(); for (i = 0; i < 8; ++i) { bd.setPixel(x + i, y, palette[col >> (7 - i) & 0x01]); } } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 4bit RLE */ private function decode4bitRLE():void { var x:int; var y:int; var i:int; var n:int; var col:int; var data:uint; var buf:ByteArray = new ByteArray(); try { for (y = nHeight - 1; y >= 0; --y) { buf.length = 0; while (bytes.bytesAvailable > 0) { n = bytes.readUnsignedByte(); if (n > 0) { // encode data data = bytes.readUnsignedByte(); for (i = 0; i < n / 2; ++i) { buf.writeByte(data); } } else { n = bytes.readUnsignedByte(); if (n > 0) { // abs mode bytes.readBytes(buf, buf.length, n / 2); buf.position += n / 2; if (n / 2 + 1 >> 1 << 1 != n / 2) { bytes.readUnsignedByte(); } } else { // EOL break; } } } buf.position = 0; for (x = 0; x < nWidth; x += 2) { col = buf.readUnsignedByte(); bd.setPixel(x, y, palette[col >> 4]); bd.setPixel(x + 1, y, palette[col & 0x0f]); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 4bit (no Compression) */ private function decode4BitBMP():void { var x:int; var y:int; var i:int; var col:int; var buf:ByteArray = new ByteArray(); var line:int = nWidth / 2; if (line % 4 > 0) { line = ((line / 4 | 0) + 1) * 4; } try { for (y = nHeight - 1; y >= 0; --y) { buf.length = 0; bytes.readBytes(buf, 0, line); for (x = 0; x < nWidth; x += 2) { col = buf.readUnsignedByte(); bd.setPixel(x, y, palette[col >> 4]); bd.setPixel(x + 1, y, palette[col & 0x0f]); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 8bit( RLE Compression ) */ private function decode8BitRLE():void { var x:int; var y:int; var i:int; var n:int; var col:int; var data:uint; var buf:ByteArray = new ByteArray(); try { for (y = nHeight - 1; y >= 0; --y) { buf.length = 0; while (bytes.bytesAvailable > 0) { n = bytes.readUnsignedByte(); if (n > 0) { // encode data data = bytes.readUnsignedByte(); for (i = 0; i < n; ++i) { buf.writeByte(data); } } else { n = bytes.readUnsignedByte(); if (n > 0) { // abs mode data bytes.readBytes(buf, buf.length, n); buf.position += n; if (n + 1 >> 1 << 1 != n) { bytes.readUnsignedByte(); } } else { // EOL break; } } } buf.position = 0; for (x = 0; x < nWidth; ++x) { bd.setPixel(x, y, palette[buf.readUnsignedByte()]); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 8bit(no Compression) */ private function decode8BitBMP():void { var x:int; var y:int; var i:int; var col:int; var buf:ByteArray = new ByteArray(); var line:int = nWidth; if (line % 4 > 0) { line = ((line / 4 | 0) + 1) * 4; } try { for (y = nHeight - 1; y >= 0; --y) { buf.length = 0; bytes.readBytes(buf, 0, line); for (x = 0; x < nWidth; ++x) { bd.setPixel(x, y, palette[buf.readUnsignedByte()]); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 16bit */ private function decode16BitBMP():void { var x:int; var y:int; var col:int; try { for (y = nHeight - 1; y >= 0; --y) { for (x = 0; x < nWidth; ++x) { col = bytes.readUnsignedShort(); bd.setPixel(x, y, (((col & nRMask) >> nRPos) * 0xff / nRMax << 16) + (((col & nGMask) >> nGPos) * 0xff / nGMax << 8) + (((col & nBMask) >> nBPos) * 0xff / nBMax << 0)); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 24bit BMP */ private function decode24BitBMP():void { var x:int; var y:int; var col:int; var buf:ByteArray = new ByteArray(); var line:int = nWidth * 3; if (line % 4 > 0) { line = ((line / 4 | 0) + 1) * 4; } try { for (y = nHeight - 1; y >= 0; --y) { buf.length = 0; bytes.readBytes(buf, 0, line); for (x = 0; x < nWidth; ++x) { bd.setPixel(x, y, buf.readUnsignedByte() + (buf.readUnsignedByte() << 8) + (buf.readUnsignedByte() << 16)); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * decode 32bit BMP */ private function decode32BitBMP():void { var x:int; var y:int; var col:int; try { for (y = nHeight - 1; y >= 0; --y) { for (x = 0; x < nWidth; ++x) { col = bytes.readUnsignedInt(); bd.setPixel(x, y, (((col & nRMask) >> nRPos) * 0xff / nRMax << 16) + (((col & nGMask) >> nGPos) * 0xff / nGMax << 8) + (((col & nBMask) >> nBPos) * 0xff / nBMax << 0)); } } } catch (e:IOError) { throw new VerifyError("invalid image data"); } } /** * check color mask */ private function checkColorMask():void { if ((nRMask & nGMask) | (nGMask & nBMask) | (nBMask & nRMask)) { throw new VerifyError("invalid bit fields"); } while (((nRMask >> nRPos) & 0x00000001) == 0) { nRPos++; } while (((nGMask >> nGPos) & 0x00000001) == 0) { nGPos++; } while (((nBMask >> nBPos) & 0x00000001) == 0) { nBPos++; } nRMax = nRMask >> nRPos; nGMax = nGMask >> nGPos; nBMax = nBMask >> nBPos; } /** * print information */ public function traceInfo():void { trace("---- FILE HEADER ----"); trace("nFileSize: " + nFileSize); trace("nReserved1: " + nReserved1); trace("nReserved2: " + nReserved2); trace("nOffbits: " + nOffbits); trace("---- INFO HEADER ----"); trace("nWidth: " + nWidth); trace("nHeight: " + nHeight); trace("nPlains: " + nPlains); trace("nBitsPerPixel: " + nBitsPerPixel); if (nInfoSize >= 40) { trace("nCompression: " + nCompression); trace("nSizeImage: " + nSizeImage); trace("nXPixPerMeter: " + nXPixPerMeter); trace("nYPixPerMeter: " + nYPixPerMeter); trace("nColorUsed: " + nColorUsed); trace("nColorUsed: " + nColorImportant); } if (nInfoSize >= 52) { trace("nRMask: " + nRMask.toString(2)); trace("nGMask: " + nGMask.toString(2)); trace("nBMask: " + nBMask.toString(2)); } } } }

BMP 파일을 선택하시면 Image 컴포넌트에 깔끔하게 출력되는 것을 보실 수 있습니다.

하지만 다음과 같은 버그가 존재합니다.

170픽셀 16bit BMP

171픽셀 16bit BMP 파일

위의 이미지에서 볼수 있는 것 처럼 BMP을 로드했을 때 이미지가 뒤틀려버리는 버그가 존재합니다.
왜 그럴까 한참을 고민했는데, 저희 팀장님이 힌트를 주시더군요. '윈도우어플에서도 비트맵 크기가 홀수일 경우 이미지가 저렇게 깨진다'고 말이죠. 실제로 테스트해보니 위와 같이 16bit이고 이미지의 너비가 홀수일 경우 위 처럼 이미지가 뒤틀려버리는 버그가 있습니다. (24bit, 32bit에서는 괜찮더군요)

이 버그에 해결책으로 저는 아래와 같이 decode() 메소드에서 이미지 너비를 결정해주는 로직 밑에 너비가 홀수일경우 강제로 1픽셀 늘리는 방법을 사용했습니다. 더 좋은 방법이 있을 것 같은데, 아시는 분은 알려주세요 :)

그럼 좋은 하루되세요!

예제파일 다운로드 :

invalid-file

'Dev > ActionScript' 카테고리의 다른 글

[ActionScript] Array를 왜 Hash로 쓰나요? Object 놔두고. (21)	2009.07.01
[Flex&Flash] useCodePage = true 가 한글 깨짐 방지 코드라고? (26)	2009.03.27
[Flex] with 를 아십니까? (12)	2008.06.09
[Flex] int나 uint보다 Number를 쓰세요! (29)	2008.06.05
[Flex] for문 쓸때 조건문에 유의하자. (23)	2008.05.09

안녕하세요? 검쉰입니다. 오랫만에 블로그 포스트로 인사드립니다.
그동안 티스토리에서 문제가 되었던 Flash Player 10에서 swf 로드가 안되던 문제가 해결이 되었네요. ;) 기존의 제 포스트들도 정상으로 보이고요. 이사하려다가 그 것또한 귀차니즘에 의해 좌절. ^ㅂ^; 아무튼 다시 오랫만에 글로 인사드려요. ;^)

흔히 자주 쓰시는 Flash로 만든 네비케이터 바 에서 메뉴정보를 외부의 XML 로 받아오는 경우와 같이 외부의 데이터를 읽어오는 과정에서 한글이 깨지는 경험을 한번쯤은 하셨을 겁니다. 이런 경우 커뮤니티에서 검색해보시면 System.useCodePage = true; 를 넣어라. 라는 답변을 많이 볼 수 있습니다. 심지여 이 것을 "한글 깨짐 방지 코드"라고 부르는 경우도 있더군요. 옛 속담에 '선무당이 사람잡는다'라는 이야기가 있습니다. 정확하게 이해하지 못하고 쓰게 되면 뒷일 감당하기 힘들게 되는 법!!. 왜 System.useCodePage = true; 를 넣으면 한글이 안꺠지는지 알아보도록 하겠습니다.

'EUC-KR' 이라고 많이 보셨을 겁니다. 한글을 정의한 캐릭터 셋(charset)입니다. 보통 한글 윈도우에서 제작한 파일은 'EUC-KR' 캐릭터 셋으로 저장되는 경우가 많습니다. 이 때 캐릭터 셋이란 글자들의 집합을 정의한 것이라고 생각하시면 됩니다. (보다 자세한 건 위키백과의 설명을 참조하시길 바랍니다.)
이러한 캐릭터 셋이 다르게 되어 있는 데이터를 읽어오게 되면 한글이 깨지게 되는데요, Flash 내부에서는 유니코드(UTF-8)를 기본으로 사용하기 때문입니다. 'EUC-KR'로 제작된 파일을 'UTF-8'로 읽었으니 당연히 서로 다른 캐릭터 셋을 사용하게 되므로 한글이 깨지게 되는 겁니다. 이러한 경우에 바로 System.useCodePage = true; 를 사용하면 한글이 깨어지지 않는데, 그 이유는 LiveDocs 에도 잘 나와있습니다.

useCodePage

속성

useCodePage:Boolean [읽기/쓰기]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9

Flash Player에서 외부 텍스트 파일을 해석하는 데 사용할 코드 페이지를 지정하는 부울 값입니다. 이 속성을 false로 설정하면 외부 텍스트 파일이 유니코드로 해석됩니다. 이러한 파일은 저장할 때 유니코드로 인코딩되어야 합니다. 이 속성을 true로 설정하면 외부 텍스트 파일이 Flash Player가 실행되는 운영 체제의 일반 코드 페이지로 해석됩니다. useCodePage의 기본값은 false입니다.

flash.display.Loader.load(), flash.net.URLLoader, flash.net.URLStream 또는 XML 클래스를 사용하여 외부 파일로 로드하는 텍스트를 Flash Player에서 유니코드로 인식하려면 이러한 파일을 유니코드로 저장해야 합니다. 외부 파일을 유니코드로 인코딩하려면 Windows 2000의 메모장과 같이 유니코드를 지원하는 응용 프로그램에서 파일을 저장해야 합니다.

유니코드로 인코딩되지 않은 외부 텍스트 파일을 로드하려면 useCodePage를 true로 설정합니다. 이렇게 하려면 데이터를 로드하는 SWF 파일의 첫 번째 프레임에 다음 코드를 첫 코드 행으로 추가합니다.

System.useCodePage = true;

이 코드를 추가하면 외부 텍스트가 Flash Player가 실행되고 있는 운영 체제의 일반 코드 페이지로 해석됩니다. 영문 Windows 운영 체제의 경우 대개 CP1252이고 한국어 운영 체제의 경우 EUC-KR입니다. 만약 useCodePage를 true로 설정하면 Flash Player 6 이상 버전은 Flash Player 5와 같은 방법으로 텍스트를 처리합니다. Flash Player 5에서는 모든 텍스트를 Flash Player 실행 운영 체제의 일반 코드 페이지를 사용하는 것으로 간주하고 처리했습니다.

useCodePage를 true로 설정하는 경우 플레이어가 실행되는 운영 체제의 일반 코드 페이지에 외부 텍스트 파일에 사용되는 문자가 포함되어 있어야 텍스트가 표시됩니다. 예를 들어 중국어 문자가 포함된 외부 텍스트 파일을 로드하는 경우 CP1252 코드 페이지에는 중국어 문자가 없으므로 이 코드 페이지를 사용하는 시스템에서 중국어 문자가 표시되지 않습니다.

모든 플랫폼에서 SWF 파일에 사용된 외부 텍스트 파일을 볼 수 있게 하려면 모든 외부 텍스트 파일을 유니코드로 인코딩하고 useCodePage를 false로 설정된 상태로 두어야 합니다. 이렇게 하면 Flash Player 6 이상에서 텍스트가 유니코드로 해석됩니다.

LiveDocs 에도 나와 있는 것 처럼 useCodePage 를 true로 설정하면 유니코드가 아닌 운영체제의 codepage로 해석이 되는 것이죠. 한글 윈도우의 기본 codePage는 'EUC-KR(51949)' 입니다. 그래서 외부의 'EUC-KR'로 되어있는 문서가 깨지지 않고 읽히게 되는 것입니다.

더 이상의 문제가 없어보입니다만, 실제 그렇지 않습니다. 해당 swf 를 로드하는 사용자가 외국어 OS를 사용하고 있다면 어떨까요? 열심히 만든 어플을 정식으로 런칭했는데, 그걸 외국의 한국인이 본다면???

이론적으로 보면 'EUC-KR'로 되어 있는 문서를 해당 OS의 codePage로 읽게 될텐데, 다른 언어의 OS는 codePage가 설마 'EUC-KR(51949)'일까요?? 위의 livedocs의 설명에도 나와 있듯, 다른 나라의 OS는 한국어 OS와 codePage가 다르다는 군요. (다른 나라 언어의 캐릭터 셋에 대해서 궁금하시다면 여기에서 확인해보시면 되겠습니다.)

실제로 그런지 확인을 위해서 아래와 같은 간단한 swf 파일을 만들어 봤습니다. 소스코드는 다음과 같습니다.
Flex 로 만든 App.

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="init()" fontSize="12" width="250" height="250">
	<mx:Script>
		<![CDATA[
		private function init():void
		{
			System.useCodePage = true;
		
			var loader:URLLoader = new URLLoader();
			configureListeners(loader);
		
			var request:URLRequest = new URLRequest("./assets/xml/data(euc-kr).xml");
		
			try 
			{
				loader.load(request);
			} 
			catch (error:Error) 
			{
				trace("Unable to load requested document.");
			}
		}
		
		private function configureListeners(dispatcher:IEventDispatcher):void 
		{
			dispatcher.addEventListener(Event.COMPLETE, completeHandler);
			dispatcher.addEventListener(Event.OPEN, openHandler);
			dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
			dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
			dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
			dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
		}
		
		private function completeHandler(event:Event):void {
			var loader:URLLoader = URLLoader(event.target);
			trace("completeHandler: " + loader.data);
			var myXML:XML = new XML(loader.data.toString());
			
			myTextArea.text = myXML.FLEX.DESC[0];
		}
		
		private function openHandler(event:Event):void {
			trace("openHandler: " + event);
		}
		
		private function progressHandler(event:ProgressEvent):void {
			trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
		}
		
		private function securityErrorHandler(event:SecurityErrorEvent):void {
			trace("securityErrorHandler: " + event);
		}
		
		private function httpStatusHandler(event:HTTPStatusEvent):void {
			trace("httpStatusHandler: " + event);
		}
		
		private function ioErrorHandler(event:IOErrorEvent):void {
			trace("ioErrorHandler: " + event);	
		}
		]]>
	</mx:Script>
	<mx:TextArea id="myTextArea" right="10" left="10" top="38" bottom="10"/>
	<mx:Label text="System.useCodePage = true;" top="10" left="10"/>
</mx:Application>

로드한 XML 파일

동일한 XML 파일을 'UTF-8', 'EUC-KR'로 각각 저장해서 useCodePage를 각각 false, true 로 설정해 영어, 일어 Windows 에서 IE로 읽어봤습니다.
클릭하셔서 확인해보세요.

Windows XP 영문판에서 swf 로드

Windows XP 일어판에서 swf 로드

UTF-8로 되어있는 파일은 어떤 OS든지 간에 잘 로드가 되고 있고, 'EUC-KR'로 되어있는 것을 System.useCodePage = true; 로 설정한 것은 한글이 여지없이 깨져보이는 것을 확인 할 수 있습니다. 외국에 서비스 할 생각이 없는 어플이라 하더라도, 기본적으로 'UTF-8'로 파일들을 저장해 놓으시면 한글문제를 잘 피해가실 수 있다고 생각합니다. 단순이 파일만이 아니라, HTTPService로 load 하는 데이터 또한 'UTF-8' 로 제작되어야 하겠죠?

하지만 할 수 없이 'EUC-KR'을 사용해야 할 때가 있습니다.네이버 카페의 경우 'EUC-KR'로 되어 있는데요, 이 것 때문에 useCodePage를 true로 설정할 수 는 없는 것 아니겠습니까? 이런 고민을 제가 존경하는 원강민님께서 블로그에 이미 포스팅 하신 적이 있습니다.
System.useCodePage 대신 이렇게.. 이 포스트를 참고 하시면 좋겠습니다.

간만에 글을 썼더니 꽤나 길어졌네요 :-) 다들 좋은 주말 되시길!

저작자표시 비영리 변경금지

'Dev > ActionScript' 카테고리의 다른 글

[ActionScript] Array를 왜 Hash로 쓰나요? Object 놔두고. (21)	2009.07.01
[Flex & Flash] ActionScript 3.0에서 BMP 파일 로드하기 (11)	2009.06.18
[Flex] with 를 아십니까? (12)	2008.06.09
[Flex] int나 uint보다 Number를 쓰세요! (29)	2008.06.05
[Flex] for문 쓸때 조건문에 유의하자. (23)	2008.05.09

ActionScript 3.0 에 명령문(statement)중에 with 를 아십니까?

사용법
with (object:Object) {
// 명령문(statement)
}

출처 : flexdocs.kr

아래의 코드는 dataXML의 XML 데이터를 읽어 해당 컴포넌트를 화면에 동적 추가하는 예제입니다.

private var dataXML:XML = 
	<root>
		<components>
			<component type="mx.containers.Canvas" id="canvas1" x="44" y="126" width="34" height="88"
				backgroundColor="0xFF0000" cornerRadius="20" borderStyle="solid" />
			<component type="mx.containers.Canvas" id="canvas2" x="44" y="30" width="422" height="88"
				backgroundColor="0x00F0FF" cornerRadius="20" borderStyle="solid" />
			<component type="mx.containers.Canvas" id="canvas3" x="229" y="126" width="237" height="88"
				backgroundColor="0x0030FF" cornerRadius="20" borderStyle="solid" />
			<component type="mx.containers.Canvas" id="canvas4" x="86" y="126" width="135" height="88"
				backgroundColor="0x24FF00" cornerRadius="20" borderStyle="solid" />
		</components>
	</root>;	// 추가될 객체 정보

// 컴포넌트 추가							
public function addComponent():void
{
	var componentList:XMLList = dataXML..component;
	var counter:int = componentList.length();
	var canvas:Canvas = null;
					
	for(var i:int=0; i<counter; i++)
	{
		var ClassReference:Class = getDefinitionByName( componentList[i].@type ) as Class;	
		var target:UIComponent = new ClassReference();	// 객체 할당하기
		
		target.id = componentList[i].@id;
		target.x = componentList[i].@x;
		target.y = componentList[i].@y;
		target.width = componentList[i].@width;
		target.height = componentList[i].@height;
		target.setStyle("backgroundColor", componentList[i].@backgroundColor);
		target.setStyle("cornerRadius", componentList[i].@cornerRadius);
		target.setStyle("borderStyle", componentList[i].@borderStyle);
			// 값 설정

this.addChild(target);	// 추가
	}
	
}

위의 코드에서 addComponent() 메소드에 보면 각종 값들을 할당하는 구문이 있습니다.
target.속성 = 값;
이런 식인데, with를 쓰면 target이라고 계속 할당하지 않아도 됩니다. 아래는 with를 사용하여 addComponent() 메소드를 수정한 예제입니다.

가장 큰 목적은 작성해야 하는 코드의 양을 줄여준다는 겁니다. (확실히 테스트 해보지는 않았지만, with를 쓰면 극소량의 용량이 늘어나는 듯도 하네요.) 위의 수정된 addComponent() 메소드를 반영한 결과물입니다. ~~결론은 잘 된다는 거죠. ;)~~ 코드의 양만 줄여줄뿐 헷갈리고 퍼포먼스도 떨어진다고 합니다. 그냥 이런 것이 있다는 것만 알아두시면 되겠네요.

참고 : ActionSctipt 3.0 의 Label 에 대해서 알아봅시다.

'Dev > ActionScript' 카테고리의 다른 글

[ActionScript] Array를 왜 Hash로 쓰나요? Object 놔두고. (21)	2009.07.01
[Flex & Flash] ActionScript 3.0에서 BMP 파일 로드하기 (11)	2009.06.18
[Flex&Flash] useCodePage = true 가 한글 깨짐 방지 코드라고? (26)	2009.03.27
[Flex] int나 uint보다 Number를 쓰세요! (29)	2008.06.05
[Flex] for문 쓸때 조건문에 유의하자. (23)	2008.05.09

이 글은 http://kuwamoto.org/ 에 올라온 Avoid ints in ActionScript의 번역 포스팅입니다.
에이레네님이 올리신 글을 보고 알게 된 포스트인데 상당히 좋은 내용이라서 번역하여 올려봅니다.
엉터리로 번역되었을 가능성 다분함.. 태클환영..;

2009. 8. 19. 내용 추가

이 글은 작성시 부터 여러 많은 개발자 분들이 내용에 오류가 있다고 지적해주셨습니다. 글의 내용에 대해서 지적해주시고 하는 것은 정말 감사드립니다. 제가 부족한 점이 많아 이해를 제대로 못하였거나, 글 작성에 문제가 있을 수 있기때문에 여러분의 덧글 하나하나가 정말 도움이 많이 되고 있습니다.

제가 본문을 수정하거나 혹은 이 글을 삭제하려고 했으나, 혹시 필요하신 분들이 있을 것 같아 본문을 수정하거나 삭제하지는 않겠습니다. 글을 다 읽으신 후 밑에 다른 분들의 덧글도 읽어보시면 더욱 좋은 것들을 배우실 수 있다고 생각합니다.

ActionScript 에서 int는 피하자구요!
Flex에 대해 알아갈수록, int에 대해서 알게 될수록, int를 사용하지 않게 되었습니다.
int가 정말 필요하지 않는 이상 int는 더 이상 사용하지 않을 것입니다.

이유 1 : Number가 int보다 실제적으로 더 빠릅니다.

놀랍게도, 사실입니다. ECMAScript Edition 4는 ECMAScript 이전 버전과 호환이 가능하게 설계되었습니다.
그래서 수학적으로 완전 무결하게 옳다라는 것을 보장하기가 어렵습니다.

어떤 방법이 더 빠를 것 같은가요? 제가 사용하는 컴퓨터에서는 int 를 사용하여 331ms 걸렸고, Number 는 291ms 걸렸습니다.

▲ 실제로 이 글을 읽는 분이 걸린 시간.

왜 그럴까요? 다음의 표현식을 보시죠.

만약 여러분이 j = 2^23 - 1 로 값을 시작했으면 어떠할 것 같습니까? 일부 프로그래밍 언어에서는 15번 더하자 마자 오버플로우 문제가 나타날 것입니다. 그러나 ECMAScript는 수의 개념이 좀 느슨합니다. 시스템에서 필요시 int에서 double로 변환되는 것을 지원하고 있습니다. 이 때문에 실질적으로 모든 수학적 계산은 내부적으로 int가 아니라 Number로 합니다.

Number로 모든 것이 완료되는 것을 감안해보면 int를 Number로 변환하는 비용과 그 만큼의 시간이 왜 int 를 사용하면 시간이 더 걸리는지에 대한 이유입니다.

다음은 Number는 실제로 int 보다 정확하게 정수 값을 저장시키기 때문에, int보다 Number 를 써야 되는 이유입니다.

이유 2 : Number는 더 많은 bit를 가집니다.

이 이유는 후에 확실하게 할게된 Number에 대한 놀라운 사실입니다. 어떻게 알게된 것인지 설명해보겠습니다.

Date 객체에는 1970년 1월 1일 자정 부터의 시간을 milliseconds 단위의 숫자로 반환하는 time 이라는 속성이 있습다. 그 값은 정수형 값이고 ActionScript에는 long 타입이 없기 때문에, 반환 타입이 진짜 int (아니면 아마도 uint) 라고 가정했습니다.

var time : uint = (new Date()).time;

왜 버그가 나는 걸까요?
back of the envelope calculation 에서 1970년 1월 1일부터 2^32 milisecond 보다 더 값을 가지기 때문에 결과가 오버플로우 난다는 것을 알려주고 있습니다. 바보같은 실수죠.

int로 받으면 2,129,587,200, Number로 받으면 1,209,015,397,376. (2008년 4월 24일 기준)
위의 값으로 Date() 객체에 다시 넣어보면 각각 1970년 1월 26일, 2008년 4월 24일 이 출력됨. - 검쉰

그렇다면 int의 bit보다 더 큰 수를 써야할 때, ActionScript는 Long 타입이 없는 상태에서 어떻게 오버플로우나 이런 부정확한 값을 해결할 수 있을까요?

var time : Number = (new Date()).time;

속을 살펴보면, Number는 아래에 있는 숫자형을 포함하고 있습니다.

int
uint
IEEE double

저는 항상 정수의 계산를 위해 double 형태를 사용하는 것을 피했습니다. 왜냐하면 모든 자리수가 보존될 것이라고 전혀 확신할 수 없었기 때문입니다. 왜냐하면, 개인적인 견해로는 정확성 측면에서 보자면 double은 int 보다 더 큰 범위의 수를 저장하기 때문입니다.

결국엔 ActionScript 의 경우에, Number는 더 큰 수의 범위를 저장할 수 있습니다. 그리고 어떤 정수형보다 정확합니다. 그건 아마도 ActionScript 는 64bit 의 정수형 타입이 없기 때문인 것 같습니다.

IEEE double 포멧은 다음과 같이 구현되어 있습니다.

S EEEEEEEEEEE FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF 0 1 11 12 63

부호를 위한 1 bit, 지수를 위한 11 bit, 숫자부분을 위한 52 bit. 따라서, 정밀도의 손실 없이 int보다 더 큰 bit의 수를 확실히 저장할 수 있습니다.

언제 int를 사용해야 될까요?

다음은 int의 적당한 사용방법입니다.

메모리를 절약하고 싶을 때 (비록 아주아주 많은 양의 저장공간이 있다 하더라도 결국에는 좋지 않은 영향을 줄 것입니다)
정수 값으로 강제변환 시 (예를 들어 var i: int = j / 2)
클라이언트에서 서버쪽으로 정수값을 보낼 때 버그를 줄이기 위해서 (값 전달용 객체안에 int 필드가 있을 때).

이제 다 설명했으니, 저는 이제 제 코드의 대부분의 Number를 확인해 볼 것입니다.

4. loop 시에 카운터로 사용 - 예를 들어 for(var i:int = 0; i < X.length; i++)

--- 2008년 6월 16일에 추가

참고 : 제가 추가로 좀 더 서술하자면, 위에서 int보다 Number가 더 빠르다는 것은 특정 상황에 대해서 그렇다는 것입니다.

int로 어떤 연산을 진행하는 것이 int보다 더 큰 Number로 연산을 진행하는 것 보다 더 빠른 것이 당연합니다. int가 Number보다 처리해야할 bit가 적으니까요. (var i:int = 0; i++; 이런경우) 다만, int형으로 연산중에 int형의 크기보다 더 큰 수를 처리해야하는 경우에 다른 언어에서는 잘못된 값이 출력이 됩니다만(이유 2에서 이런 문제를 지적하고 있습니다), AS3는 자동으로 Number 로 변환하여 연산을 진행합니다.
이런 이유에서 "int가 내부적으로 Number로 변환되는(int의 크기를 넘어서는 연산) 경우에는 Number로 진행하는 것이 더 빠르다." 라는 것이 이 포스트의 속도 문제에서의 핵심입니다.

원저자가 약간 int에 대한 매우 안좋은 감정이 있긴 한 모양입니다만, 이 글을 보신 분들은 때에 따라서 잘 사용하시면 좋겠죠?

'Dev > ActionScript' 카테고리의 다른 글

[ActionScript] Array를 왜 Hash로 쓰나요? Object 놔두고. (21)	2009.07.01
[Flex & Flash] ActionScript 3.0에서 BMP 파일 로드하기 (11)	2009.06.18
[Flex&Flash] useCodePage = true 가 한글 깨짐 방지 코드라고? (26)	2009.03.27
[Flex] with 를 아십니까? (12)	2008.06.09
[Flex] for문 쓸때 조건문에 유의하자. (23)	2008.05.09

머드초보님의 블로그 포스트에서 알게된 책중에 자바 성능을 결정짓는 코딩 습관과 튜닝 이야기란 책이 있습니다. 제목이 너무 맘에 들어 바로 사서 요즘 출퇴근 길에 열독 하고 있습니다.

잠 시 책 소개를 하자면, 초보 개발자 '나초보' 씨가 실력있는 선배 '김경험', '이튜닝' 같은 분들에게 하나씩 배워가는 스토리로 쓰여 있습니다. 참 읽기 편하네요. 저 역시 '나초보' 와 그닥 다를 바 없는 실력 형편없는 개발자인지라 공감도 많이 되고, 많이 읽으면서 배우고 있습니다. 저자이신 '이상민'님 정말 감사합니다. ;)

참 유용하니 꼭 읽어보시길 권해드립니다.

아무튼, 상당히 유용한 이야기들로 가득차 있는데요, 책 내용 중 간단하게 언급된 for문 관련 이야기중 ActionScript를 쓰는 개발자들에게도 유용할 것 같은 Tip 이라 포스팅해봅니다. (사실 저 같은 어리버리 개발자한테만 유용할지도?)

for문은 상당히 많이 쓰는 loop 중에 하나입니다.
하지만 프로그래머들이 흔히 간과할 수 있는 부분이 있습니다.
우선 for문에 대해서 알아봅시다.

for 루프를 사용하면, 특정의 범위의 값에 대한 변수의 반복 처리를 실행할 수가 있습니다.
for 명령문(statement)에는, 3 개의 식을 지정할 필요가 있습니다.
해당 식은,
1. 초기치로 설정하는 변수
2. 루프가 언제 종료하는지를 지정하는 조건문(conditional statement )
3. 각 루프로 변수의 값을 변경하는 식 입니다.
예를 들어, 다음의 코드는 5 회 루프 합니다. 변수 i 는 0 으로 시작되어, 4 로 끝납니다.
출력은 0 ~ 4 의 수치가 되어, 각 수치는 개별의 행에 출력됩니다.

출처 : flexdocs.kr

여기서 눈여겨 봐야할 것은 2번째 조건문 입니다.
만약 Array 에 값을 for 루프를 돌아 처리한다고 할 때, 흔히 아래와 같이 쓰게 됩니다.

var i:int; // loop 용 카운터 var j:Number; // Array의 값을 입력할 변수 for(i=0 ; i<dataArray.length; i++) { j = dataArray[i]; }

이 때 2번째 조건 명령문에 들어있는 dataArray.length 가 문제가 됩니다. 루프를 도는 도중에 계속 호출되어 배열의 길이를 알아오기 때문입니다.
이 것은 다음과 같이 변경하여 좀 더 빠르게 바꿀 수 가 있습니다.

var i:int; // loop 용 카운터 var j:Number; // Array의 값을 입력할 변수 var dataArrayLength:Number = dataArray.length; // 배열의 길이를 저장한 변수 for(i=0 ; i<dataArrayLength; i++) { j = dataArray[i]; }
변수 dataArrayLength에 배열의 길이를 담은 후에 조건문에 대입하므로서 불필요하게 dataArray.length 를 매번 호출하지 않아도 되죠.

이와 비슷한 경우가 종종 있을 경우가 있습니다.
예를 들어 Canvas에 있는 자식 객체들의 수를 구하기 위해 Container 클래스에 정의된 numChildren 속성을 호출한다던지 말이죠.
아래의 코드는 클릭 이벤트가 발생하면 클릭된 Canvas의 자식 객체에 대해서 어떤 동작을 하는 코드입니다.

private function clickEventHandler(evt:MouseEvent):void { var targetCvs:Canvas = evt.currentTarget as Canvas; var i:int; // 이러면 느려요! for(i=0; i<targetCvs.numChildren; i++) { // Something... } // 이렇게 해주세요! var childrenNum:Number = targetCvs.numChildren; for(i=0; i<childrenNum; i++) { // Something... } }

이제 실제 테스트를 해보겠습니다.
테스트해본 코드는 다음과 같고요, 그 아래 실제 결과물로 이 포스트를 읽는 분들이 테스트를 해보세요!

private var dataArray:Array = []; public function init():void { var i:int; for(i=0 ; i<10000000; i++) { dataArray.push(i); } // 데이터 10000000 개 입력 } public function timeTest():void { var i:int; // loop 용 카운터 var j:Number; // Array의 값을 입력할 변수 var firstTime:Number; // length 사용시 시간 var secondTime:Number; // length 미사용시 시간 //////////// 속도 측정 시작 /////////// firstTime = (new Date()).time; for(i=0 ; i<dataArray.length; i++) { j = dataArray[i]; } firstTime = (new Date()).time - firstTime; // length 사용시 속도 측정 secondTime = (new Date()).time; var dataArrayLength:Number = dataArray.length; // 배열의 길이를 저장한 변수 for(i=0 ; i<dataArrayLength; i++) { j = dataArray[i]; } secondTime = (new Date()).time - secondTime; // length 미사용시 속도 측정 //////////// 속도 측정 종료 /////////// var message : String = "length 사용시: " + firstTime + "ms\n" + "length 미사용시: " + secondTime + "ms"; Alert.show(message); }
(참고 : creationComplete 시에 init() 을 실행시켜 dataArray 에는 10,000,000개의 데이터를 넣었습니다.)

저는 length 사용시: 953ms, length 미사용시: 187ms 걸렸습니다. ;)

▲ 실제로 이 글을 읽는 분이 걸린 시간.

알고도 그냥 지나칠 수 있는 부분이니까 습관을 들이도록 합시다. ;)
긴 글 읽으신다고 고생하셨습니다.

'Dev > ActionScript' 카테고리의 다른 글

[ActionScript] Array를 왜 Hash로 쓰나요? Object 놔두고. (21)	2009.07.01
[Flex & Flash] ActionScript 3.0에서 BMP 파일 로드하기 (11)	2009.06.18
[Flex&Flash] useCodePage = true 가 한글 깨짐 방지 코드라고? (26)	2009.03.27
[Flex] with 를 아십니까? (12)	2008.06.09
[Flex] int나 uint보다 Number를 쓰세요! (29)	2008.06.05

'Dev > ActionScript' 카테고리의 다른 글

'Dev > ActionScript' 카테고리의 다른 글

'Dev > ActionScript' 카테고리의 다른 글

'Dev > ActionScript' 카테고리의 다른 글

이유 1 : Number가 int보다 실제적으로 더 빠릅니다.

이유 2 : Number는 더 많은 bit를 가집니다.

언제 int를 사용해야 될까요?

'Dev > ActionScript' 카테고리의 다른 글

'Dev > ActionScript' 카테고리의 다른 글

티스토리툴바